$Assumptions = {n \[Element] Integers, m \[Element] Integers};
f[n_, x_] := Sqrt[2] Sin[n \[Pi] x];
s[n_, m_] := 
 Function[{x, y}, (f[n, x] f[m, y] + f[n, y] f[m, x])/Sqrt[2]];
swave2 = Plot3D[Evaluate[-s[3, 1][x, y]], {x, 0, 1}, {y, 0, 1},
  PlotPoints -> 35,
  PlotRange -> {-2.5, 3.5},
  MeshFunctions -> {#3 &},
  MeshStyle -> 
   Directive[ColorData["DeepSeaColors"][.1], Thickness[.002]],
  Mesh -> 10,
  ColorFunction -> "LakeColors",
  BoxRatios -> {1, 1, .7},
  Boxed -> False,
  Axes -> False];
sgroundplot = Plot3D[-3, {x, 0, 1}, {y, 0, 1},
  MeshFunctions -> {s[1, 3][#1, #2] &},
  Mesh -> 10,
  MeshStyle -> 
   Directive[ColorData["DeepSeaColors"][.1], Thickness[.002]],
  PlotPoints -> 50,
  ColorFunction -> (ColorData["LakeColors"][(-s[1, 3][#1, #2] + 2.5)/
      6] &)];
swave3 = Show[{swave2, sgroundplot},
 PlotRange -> {{0, 1}, {0, 1}, {-3, 3}},
 Axes -> None,
 PlotRangePadding -> None,
 ImagePadding -> 1,
 FaceGrids -> {
   {{-1, 0, 0}, {Table[i, {i, 0, 1, 1/9}], 
     Table[i, {i, -3, 3, 1}]}},
   {{0, -1, 0}, {Table[i, {i, 0, 1, 1/9}], Table[i, {i, -3, 3, 1}]}}
   },
 ViewPoint -> 1000 {5, 5, 2},
 ViewVertical -> {0, 0, 1},
 ViewCenter -> {.5, .5, 0},
 ImageSize -> 600]
Export["Symmetricwave2.png", swave3, "PNG"]