User:Máté: Difference between revisions
Jump to navigation
Jump to search
Content deleted Content added
No edit summary |
Tag: 2017 source edit |
||
Line 152: | Line 152: | ||
}} |
}} |
||
|} |
|} |
||
{{SPARQL|query= |
|||
SELECT ?film ?filmLabel (count(distinct ?p) AS ?numberOfRatingProperties) |
|||
WHERE { |
|||
[] wdt:P31 wd:Q24716199; wikibase:claim ?p . |
|||
?film wdt:P31/wdt:P279* wd:Q11424; ?p [] . |
|||
SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en" . } |
|||
} GROUP BY ?film ?filmLabel ORDER BY DESC(?numberOfRatingProperties) LIMIT 10 |
|||
}} |
|||
;Icon of Hungarian film rating (?hun): |
;Icon of Hungarian film rating (?hun): |
||
<source lang="sparql">{ ?item wdt:P2363/wdt:P18 ?hun . } UNION { ?item wdt:P2747/wdt:P18 ?hun . FILTER NOT EXISTS { ?item wdt:P2363 ?new . } }</source> |
<source lang="sparql">{ ?item wdt:P2363/wdt:P18 ?hun . } UNION { ?item wdt:P2747/wdt:P18 ?hun . FILTER NOT EXISTS { ?item wdt:P2363 ?new . } }</source> |
Revision as of 10:04, 20 March 2017
Babel user information | ||||||||
---|---|---|---|---|---|---|---|---|
| ||||||||
Users by language |
|
Hi! I'm Máté (pronounced [ˈmaːteː]) from Hungary (Q28). I'm most frequent on huwiki. I studied
- international business (Q3681519) & entrepreneurship (Q3908516) at Corvinus University of Budapest (Q851164) (BA),
- history of film (Q107478) & film theory (Q28793) major with editing (Q194105) minor at Eötvös Loránd University (Q390287) (BLA),
- and cultural economics (Q1791932) & entrepreneurship (Q3908516) at Erasmus University Rotterdam (Q633529) (MA).
Proposed properties
- PORT film ID (P905)
- Box Office Mojo film ID (former scheme) (P1237)
- Rotten Tomatoes ID (P1258)
- NMHH film rating (P2363)
- PORT person ID (P2435)
- NAVA ID (P2475)
- MTMT author ID (P2492)
- OM institution ID (P2493)
- Box Office Mojo franchise ID (former scheme) (P2530)
- Box Office Mojo studio ID (P2531)
- production designer (P2554)
- Hungarian company ID (P2619)
- MEK ID (P2623)
- BBFC rating (P2629)
- rating certificate ID (P2676)
- Kijkwijzer rating (P2684)
- Hungarian-style transcription (P2719)
- Filmiroda rating (P2747)
- film crew member (P3092)
- ISzDb film ID (P3110)
- ISzDb person ID (P3114)
- ISzDb company ID (P3115)
- ISzDb dub ID (P3116)
- NSZL name authority ID (P3133)
- Australian Classification (P3156)
- ClassInd rating (P3216)
- HAS member ID (P3226)
- PORT organization URL (P3268)
- ICAA rating (P3306)
- CNC film rating (Romania) (P3402)
- INCAA film rating (P3428)
- JMK film rating (P3650)
Queries
# musicals and rock operas first performed in Hungary with the list of authors
SELECT DISTINCT ?musical ?musicalLabel ?premieredate ?premiereplaceLabel
(GROUP_CONCAT(DISTINCT(?author); separator=" – ") as ?authors)
WHERE {
{ ?musical wdt:P31/wdt:P279* wd:Q2743 . }
UNION
{ ?musical wdt:P31/wdt:P279* wd:Q253137 . }
?musical p:P1191 [
ps:P1191 ?premieredate;
pq:P276 ?premiereplace
] .
?premiereplace wdt:P131+ wd:Q28
OPTIONAL { ?musical (wdt:P86|wdt:P676|wdt:P87)/rdfs:label ?author FILTER (lang(?author) = "hu") . }
SERVICE wikibase:label {
bd:serviceParam wikibase:language "hu" .
}
} GROUP BY ?musical ?musicalLabel ?premieredate ?premiereplaceLabel ORDER BY ASC(?premieredate)
# ratings of Hungarian films
SELECT DISTINCT ?film ?filmLabel ?ratingLabel ?age ?countryLabel
WHERE {
[] wdt:P31 wd:Q24716199; wikibase:directClaim ?p .
?film wdt:P31/wdt:P279* wd:Q11424;
wdt:P495 wd:Q28;
?p ?rating .
?rating wdt:P2899 ?age; wdt:P31/wdt:P361/wdt:P17 ?country .
SERVICE wikibase:label {
bd:serviceParam wikibase:language "hu,en" .
}
} ORDER BY ?filmLabel ?countryLabel
# Russian film titles without Hungarian transcriptions
SELECT ?film ?filmLabel ?title
WHERE {
?film wdt:P31/wdt:P279* wd:Q11424;
p:P1476 ?s .
?s ps:P1476 ?title .
MINUS { ?s pq:P2719 [] . }
FILTER ( lang(?title) = "ru" ) .
SERVICE wikibase:label { bd:serviceParam wikibase:language "hu" . }
}
# same-sex supercouples
SELECT DISTINCT ?item ?itemLabel ?workLabel ?sexLabel
WHERE {
?item wdt:P31 wd:Q1274180;
wdt:P527 ?one, ?two . FILTER ( ?one != ?two )
?one wdt:P21 ?sex . ?two wdt:P21 ?sex .
OPTIONAL { ?item wdt:P1441 ?work . }
SERVICE wikibase:label {
bd:serviceParam wikibase:language "en" .
}
}
# languages qualifier Hungarian-style transcription (P2719) is used with by number of statements, identified by their Hungarian labels
SELECT ?lang (COUNT(?v) AS ?num)
WHERE {
[] wikibase:propertyType wikibase:Monolingualtext;
wikibase:statementProperty ?ps .
?v pq:P2719 ?trans; ?ps ?text .
BIND (lang(?text) AS ?wmlc) .
[] wdt:P424 ?wmlc; wdt:P31 wd:Q34770; rdfs:label ?lang .
FILTER (lang(?lang) = "hu") .
} GROUP BY ?lang ORDER BY DESC(?num)
SELECT ?label (count(?film) AS ?count)
WHERE {
[] wdt:P31 wd:Q24716199; wikibase:directClaim ?p .
?film wdt:P31/wdt:P279* wd:Q11424; ?p [ wdt:P2899 ?age ] .
BIND(IF( 0 <= ?age && ?age < 3, "00-02",
IF( 3 <= ?age && ?age < 6, "03-05",
IF( 6 <= ?age && ?age < 9, "06-08",
IF( 9 <= ?age && ?age < 12, "09-11",
IF( 12 <= ?age && ?age < 15, "12-14",
IF( 15 <= ?age && ?age < 18, "15-17",
IF( 18 <= ?age, "18+", "" ) ) ) ) ) ) )
AS ?label)
} GROUP BY ?label ORDER BY ASC(?label)
|
SELECT ?label (count(?film) AS ?count)
WHERE {
[] wdt:P31 wd:Q24716199; wikibase:directClaim ?p .
?film wdt:P31/wdt:P279* wd:Q11424; ?p [ wdt:P2899 ?age ] .
BIND(IF( 0 <= ?age && ?age < 6, "00-05",
IF( 6 <= ?age && ?age < 12, "06-11",
IF( 12 <= ?age && ?age < 18, "12-17",
IF( 18 <= ?age, "18+", "" ) ) ) )
AS ?label)
} GROUP BY ?label ORDER BY ASC(?label)
|
SELECT ?film ?filmLabel (count(distinct ?p) AS ?numberOfRatingProperties)
WHERE {
[] wdt:P31 wd:Q24716199; wikibase:claim ?p .
?film wdt:P31/wdt:P279* wd:Q11424; ?p [] .
SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en" . }
} GROUP BY ?film ?filmLabel ORDER BY DESC(?numberOfRatingProperties) LIMIT 10
- Icon of Hungarian film rating (?hun)
{ ?item wdt:P2363/wdt:P18 ?hun . } UNION { ?item wdt:P2747/wdt:P18 ?hun . FILTER NOT EXISTS { ?item wdt:P2363 ?new . } }
Subpages
This is a Wikidata user page. If you find this page on any site other than Wikidata (www.wikidata.org), you are viewing a mirror site. Be aware that the page may be outdated, and that the user this page belongs to may have no personal affiliation with any site other than Wikidata itself. The original page is located at https://www.wikidata.org/wiki/User:M%C3%A1t%C3%A9. |